# This allows you to quote parts of a table.
# Copyright 2001 Blossom Associates West
# All rights reserved.

# There are variables for the various quotes.
# LTQ = left table quote (preamble)
# RTQ = right table quote (appendix)
# LRQ = left row quote (prefix)
# RRQ = right row quote (suffix)
# LFQ = left field quote
# RFQ = right field quote

# The variable FMT can be set from the command line.
# Values are "html", "csv", or "tsv".
# e.g. awk -f qTable.awk -v FMT=html input.tsv


1 == NR {

  if ( "html" == FMT ) {
    LTQ = "<table>";
    RTQ = "</table>";
    LRQ = "<tr>";
    RRQ = "</tr>";
    LFQ = "<td>";
    RFQ = "</td>";
  }

  if ( "csv" == FMT ) {
    # BUG: without quote stuffing.
    LTQ = "";
    RTQ = LTQ;
    LRQ = "";
    RRQ = LRQ;
    LFQ = "\"";
    RFQ = LFQ;
    OFS = ",";
  }

  if ( "tsv" == FMT ) {
    LTQ = "";
    RTQ = LTQ;
    LRQ = "";
    RRQ = LRQ;
    LFQ = "";
    RFQ = LFQ;
    OFS = "\t";
  }

  if ( 0 < length( LTQ ) ) {
    print LTQ;
  }
}


{
  for ( i = 1; i <= NF; i++ ) {
    $i = LFQ $i RFQ;
  }
  print LRQ $0 RRQ;
}

END {
  if ( 0 < length( RTQ ) ) {
    print RTQ;
  }
}